jaybird-manual/build.gradle at master · FirebirdSQL/jaybird-manual · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
plugins {
    id 'org.asciidoctor.jvm.convert' version '4.0.5'
    id 'org.asciidoctor.jvm.pdf' version '4.0.5'
}

defaultTasks 'clean', 'asciidoctor'

repositories {
    mavenCentral()
}

configurations {
    asciidoctorExt
}

dependencies {
    asciidoctorExt 'org.firebirdsql.asciidoctor:canonical-link:1.0'
    asciidoctorExt 'org.firebirdsql.asciidoctor:since-until-macro:1.0'
}

asciidoctorj {
    version = '3.0.1'
    modules {
        pdf {
            version '2.3.23'
        }
    }
}

asciidoctor {
    configurations 'asciidoctorExt'
    baseDirFollowsSourceDir()
    executionMode = OUT_OF_PROCESS
    sources {
        include 'jaybird_manual.adoc'
    }
    attributes 'revnumber': false, 'stylesdir': file('src/docs/theme/jaybird-html'), 'stylesheet': 'firebird.css',
            'docinfo': 'shared', 'docinfodir': file('src/docs/theme/jaybird-html/docinfo')
    jvm {
        jvmArgs "--add-opens", "java.base/sun.nio.ch=ALL-UNNAMED", "--add-opens", "java.base/java.io=ALL-UNNAMED"
    }
}

pdfThemes {
    local 'jaybird', {
        themeDir = file('src/docs/theme/jaybird-pdf')
        themeName = 'jaybird'
    }
}

asciidoctorPdf {
    configurations 'asciidoctorExt'
    baseDirFollowsSourceDir()
    executionMode = OUT_OF_PROCESS
    sources {
        include 'jaybird_manual.adoc'
    }
    attributes 'revnumber': false, 'source-highlighter': 'rouge', 'media': 'prepress', 'compress': '',
            'icon-set': 'fas', 'pdf-fontsdir': "${file('src/docs/theme/fonts')},GEM_FONTS_DIR"
    theme = 'jaybird'
    jvm {
        jvmArgs "--add-opens", "java.base/sun.nio.ch=ALL-UNNAMED", "--add-opens", "java.base/java.io=ALL-UNNAMED"
    }
}

// Create the HTML and PDF output and copy them to the build/pages folder
// Primarily intended for the GitHub Actions build to deploy to GitHub pages
tasks.register('makePages') {
    dependsOn asciidoctor, asciidoctorPdf
    doLast {
        copy {
            from asciidoctor.outputs
            into layout.buildDirectory.dir('pages')
        }
        copy {
            from asciidoctorPdf.outputs
            into layout.buildDirectory.dir('pages')
        }
        copy {
            from layout.projectDirectory.dir('src/docs/theme/jaybird-html')
            include 'favicon.ico'
            into layout.buildDirectory.dir('pages')
        }
    }
}