ktgbotapi/build.gradle at master · InsanusMokrassar/ktgbotapi · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
buildscript {
    repositories {
        mavenCentral()
        maven { url "https://plugins.gradle.org/m2/" }
        mavenLocal()
    }

    dependencies {
        classpath libs.kotlin.gradle.plugin
        classpath libs.kotlin.ksp.plugin
        classpath libs.kotlin.serialization.plugin
        classpath libs.kotlin.dokka.plugin
        classpath libs.github.release.plugin
    }
}

plugins {
    alias(libs.plugins.kotlin.dokka)
    alias(libs.plugins.versions)
    alias(libs.plugins.validator)
    alias(libs.plugins.nmcp.aggregation)
}

// docs is a dokka-only aggregator module, exclude it from binary compatibility validation
apiValidation {
    ignoredProjects += ["docs"]
}


if ((project.hasProperty('SONATYPE_USER') || System.getenv('SONATYPE_USER') != null) && (project.hasProperty('SONATYPE_PASSWORD') || System.getenv('SONATYPE_PASSWORD') != null)) {
    nmcpAggregation {
        centralPortal {
            username = project.hasProperty('SONATYPE_USER') ? project.property('SONATYPE_USER') : System.getenv('SONATYPE_USER')
            password = project.hasProperty('SONATYPE_PASSWORD') ? project.property('SONATYPE_PASSWORD') : System.getenv('SONATYPE_PASSWORD')
            validationTimeout = Duration.ofSeconds(0)
            publishingType = System.getenv('PUBLISHING_TYPE') != "" ? System.getenv('PUBLISHING_TYPE') : "USER_MANAGED"
        }

        publishAllProjectsProbablyBreakingProjectIsolation()
    }
}

// temporal crutch until legacy tests will be stabled or legacy target will be removed
allprojects {
    repositories {
        mavenCentral()
        google()
        maven { url "https://nexus.inmo.dev/repository/maven-releases/" }
        mavenLocal()
    }
    if (it != rootProject.findProject("docs")) {
        tasks.configureEach { task ->
            if(task.name == "jsLegacyBrowserTest" || task.name == "jsLegacyNodeTest") {
                task.enabled = false
            }
        }
    }
}
apply from: "./extensions.gradle"

private String getCurrentVersionChangelog() {
    return providers.exec {
        commandLine './changelog_info_retriever', "$library_version", 'CHANGELOG.md'
    }.standardOutput.asText.get().trim()
}


def githubTokenVariableName = "GITHUB_RELEASE_TOKEN"
def githubTokenVariableFromEnv = System.getenv(githubTokenVariableName)

def secretFile = new File(projectDir, "secret.gradle")
if (secretFile.exists() || project.hasProperty(githubTokenVariableName) || (githubTokenVariableFromEnv != "" && githubTokenVariableFromEnv != null)) {
    if (secretFile.exists()) {
        apply from: './secret.gradle'
    }
    apply plugin: "com.github.breadmoirai.github-release"
    def githubReleaseToken = project.hasProperty(githubTokenVariableName) ? project.property(githubTokenVariableName).toString() : githubTokenVariableFromEnv

    githubRelease {
        token githubReleaseToken

        owner = "InsanusMokrassar"
        repo = "TelegramBotAPI"

        tagName = "v$library_version"
        releaseName = "$library_version"
        targetCommitish = "$library_version"

        body = getCurrentVersionChangelog()
    }
}