build.gradle

import net.darkhax.curseforgegradle.TaskPublishCurseForge
import net.darkhax.curseforgegradle.UploadArtifact

plugins {
    id "dev.architectury.loom" version "1.10-SNAPSHOT"
    id 'net.darkhax.curseforgegradle' version '1.1.+'
}

sourceCompatibility = targetCompatibility = JavaVersion.VERSION_1_8

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

loom {
    silentMojangMappingsLicense()

    forge {
        mixinConfigs = [
            "opotato.mixins.json"
        ]
    }

    mixin.defaultRefmapName.set("opotato.refmap.json")
}

repositories {
    maven {
        url "https://cursemaven.com"
        content {
            includeGroup "curse.maven"
        }
    }
    maven { url = "https://maven.theillusivec4.top/" }
    maven { url = 'https://maven.parchmentmc.org' }
}

dependencies {
    minecraft "com.mojang:minecraft:${minecraft_version}"
    mappings loom.layered() {
        officialMojangMappings()
        parchment("org.parchmentmc.data:parchment-${minecraft_version}:${parchment_version}@zip")
    }

    forge "net.minecraftforge:forge:${project.forge_version}"
    modImplementation("curse.maven:oh-the-biomes-youll-go-247560:4024011")
    modImplementation("top.theillusivec4.curios:curios-forge:1.16.5-4.1.0.0")
    modImplementation("curse.maven:blueprint-382216:3607198")
    modImplementation("curse.maven:ars-nouveau-401955:4300733")
    modImplementation("curse.maven:blue-skies-312918:3411324")
    modImplementation("curse.maven:structure-gel-api-378802:3498310")
    modImplementation("curse.maven:l_ender-s-cataclysm-551586:4418434")
    modImplementation("curse.maven:citadel-331936:3441028")
    modImplementation("curse.maven:deuf-duplicate-entity-uuid-fix-296646:3885123")
    modImplementation("curse.maven:elenai-dodge-2-442962:3343309")
    modImplementation("curse.maven:epic-fight-mod-405076:4029362")
    modImplementation("curse.maven:female-gender-forge-481655:3459078")
    modImplementation("curse.maven:headshot-forge-538264:3501178")
    modImplementation("curse.maven:inspirations-284007:3414517")
    modImplementation("curse.maven:item-stages-280316:3482955")
    modImplementation("curse.maven:jei-238222:4371666")
    modImplementation("curse.maven:kiwi-303657:3536245")
    modImplementation("curse.maven:ldlib-626676:4124863")
    modImplementation("curse.maven:oculus-581495:4300427")
    modImplementation("curse.maven:placebo-283644:4501015")
    modImplementation("curse.maven:quark-243121:3642325")
    modImplementation("curse.maven:randompatches-forge-285612:3211323")
    modImplementation("curse.maven:supplementaries-412082:4967874")
    modImplementation("curse.maven:the-undergarden-379849:3477594")
    modImplementation("curse.maven:crackers-wither-storm-mod-621405:4403153")
    modImplementation("curse.maven:xaeros-world-map-317780:6538313")
    modImplementation("curse.maven:xaeros-minimap-263420:6515007")
    modImplementation(files("deps/industrial-foregoing-1.16.5-3.2.14.7-16.jar", "deps/titanium-1.16.5-3.2.8.8-24.jar"))
    modImplementation("curse.maven:embeddium-908741:4803825")
    modImplementation("curse.maven:modern-ui-352491:3765938")
    modImplementation("curse.maven:spark-361579:3767277")
    modImplementation("curse.maven:embeddium-extension-920353:4798284")
    modImplementation("curse.maven:charm-reforged-430988:3214651")
    modImplementation("curse.maven:neat-238372:3182258")
    modImplementation("curse.maven:dynamiclights-reforged-551736:3574974")
    modImplementation("curse.maven:brutal-bosses-dungeon-557999:3773958")
    modImplementation("curse.maven:astral-sorcery-241721:3813365")
    modImplementation("curse.maven:spiritcaller-backport-676129:3987105")
}

processResources {
    inputs.property "version", project.version
    filesMatching("META-INF/mods.toml") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = "UTF-8"
    options.release.set(8)
}

jar {
    manifest {
        attributes([
                "Implementation-Title"    : project.name,
                "Implementation-Version"  : mod_version,
                "Implementation-Vendor"   : mod_author,
                "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
        ])
    }
}

java {
    withSourcesJar()
}


String currentChangeLog = file("CHANGELOG.md").getText("UTF-8")
String[] javaVersions = ["Java 8", "Java 17", "Java 21", "Java 22"]

def cf_project_id = "834716"

tasks.register("publishCurseForge", TaskPublishCurseForge) {
    apiToken = System.getenv("CURSEFORGE_TOKEN")
    disableVersionDetection()

    UploadArtifact mainFile = upload(cf_project_id, remapJar)
    mainFile.displayName = "Opotato-${version}"
    mainFile.releaseType = "release"
    mainFile.changelog = currentChangeLog
    mainFile.changelogType = "markdown"
    mainFile.addModLoader("Forge")
    mainFile.addJavaVersion(javaVersions)
    mainFile.addGameVersion(minecraft_version)

    UploadArtifact sourcesFile = mainFile.withAdditionalFile(sourcesJar)
    sourcesFile.changelog = currentChangeLog
    sourcesFile.changelogType = "markdown"
}