build.gradle

import org.apache.tools.ant.filters.ReplaceTokens

plugins {
    id 'java-library'
    id 'maven-publish'
    id 'signing'
    id 'eclipse'
    id 'io.github.gradle-nexus.publish-plugin' version '2.0.0'
    id 'com.liferay.tlddoc.builder' version '2.0.1'
}

group = "org.opencms"

layout.buildDirectory.set(file(build_directory))

java {
    sourceCompatibility = JavaVersion.toVersion(java_target_version)
    targetCompatibility = JavaVersion.toVersion(java_target_version)
}
signing {
    useGpgCmd()
}

nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
        }
    }
}



// use the same properties file as the OpenCms core does for the version information
// please note that in a Jenkins CI build, this properties file should be dynamically generated
def externalVersionProps = layout.buildDirectory.file("../version.properties").get().asFile
def propFile;
if (externalVersionProps.exists()){
    println "Using external version properties file: $externalVersionProps"
    propFile=externalVersionProps
}else{
    println 'Using internal version properties file'
    propFile=file("$projectDir/src/org/opencms/main/version.properties")
}

Properties vprops = new Properties()
vprops.load(new FileInputStream(propFile))
if (opencms_version) {
    version = opencms_version
}else{
    version = vprops['version.number']
}

// flag, indicating if javadoc should be skipped
boolean addJavadoc = !(project.hasProperty('skip_javadoc') && skip_javadoc.toBoolean())

// alternative variable name for the case where the version variable is used for something else, e.g. javadoc
ext.ocmsVersion = vprops['version.number']

// deal with external modules project
def extModulesProject = findProject(':extmodules')
def hasExtModules = null != extModulesProject
if (hasExtModules) {
    println 'Adding coreproject property to subprojects.'
    subprojects {
        ext.coreproject = ':'
    }
}

repositories {
    if (project.hasProperty('additional_repositories')){
        additional_repositories.split(';').each{ repo ->
            maven { url = repo }
        }
    }
    mavenCentral()
    maven {
        url = 'https://maven.restlet.talend.com'
    }
    maven {
        url = 'https://maven.vaadin.com/vaadin-addons'
    }
}

if (!project.hasProperty('max_heap_size')){
    project.ext.max_heap_size='1024m'
}

project.ext.allModuleNames = modules_list.split(',')
project.ext.modulesDistsDir = layout.buildDirectory.dir("modulesZip").get().asFile


sourceSets{
    main {
        java.srcDirs=['src']
        resources.srcDirs=['src']
    }
    modules {
        java.srcDirs=['src-modules']
        resources.srcDirs=['src-modules']
    }
    gwt {
        java {
            srcDirs=['src-gwt']
            exclude '**/super_src/**'
        }
        resources {
            srcDirs=['src-gwt']
            exclude '**/super_src/**'
        }
    }
    setup {
        java.srcDirs=['src-setup']
        resources.srcDirs=['src-setup']
    }
    test {
        java {
            srcDirs=['test']
            exclude 'data/**'
        }
        resources {
            srcDirs=['test']
            exclude 'data/**'
        }
    }
    testGwt {
        java {
            srcDirs=['test-gwt']
            exclude '**/super_src/**'
        }
        resources {
            srcDirs=['test-gwt']
            exclude '**/super_src/**'
        }
    }
}

configurations {

    distribution {
        description = 'libraries included into the opencms distribution'
    }

    api {
        extendsFrom distribution
    }

    usedApis {
        description = "APIs that should normally be provided by the servlet container, but are also needed for the CmsShell, so they're bundled in the WAR."
    }

    compile {
        description = 'used to compile the opencms.jar and the modules jars'
        extendsFrom distribution
        extendsFrom usedApis
    }
    // Default configuration of the java-library plugin
    // It corresponds to our compile configuration, that's why we have to use extendsFrom here
    implementation {
        extendsFrom compile
    }

    modulesCompile {
        description = 'used to compile the modules classes'
        extendsFrom compile
    }

    // Default configuration of the java-library plugin
    // It corresponds to our compile configuration, that's why we have to use extendsFrom here
    modulesImplementation {
        extendsFrom modulesCompile
    }

    moduleDeps {
        description = 'additional dependencies required by external modules'
    }

    testCompile{
        extendsFrom modulesCompile
    }

    // Default configuration of the java-library plugin
    // It corresponds to our compile configuration, that's why we have to use extendsFrom here
    testImplementation {
        extendsFrom testCompile
        extendsFrom setupImplementation
    }

    gwtCompile {
        description = 'needed to generate the GWT JavaScript resources'
        extendsFrom modulesCompile
        exclude group: 'org.eclipse.jetty.http2'
    }

    // Default configuration of the java-library plugin
    // It corresponds to our compile configuration, that's why we have to use extendsFrom here
    gwtImplementation {
        extendsFrom gwtCompile
    }

    testGwtCompile{
        description = 'needed to run GWT test cases'
        extendsFrom gwtCompile
    }

    // Default configuration of the java-library plugin
    // It corresponds to our compile configuration, that's why we have to use extendsFrom here
    testGwtImplementation {
        extendsFrom testGwtCompile
    }

    // Fix the jetty incompatibility for the version from distribution used by Solr and the one for the GWT test cases.
    testGwtRuntimeClasspath{
       resolutionStrategy {
           eachDependency { DependencyResolveDetails details ->
                 if (details.requested.group == 'org.eclipse.jetty') {
                    details.useVersion '9.4.51.v20230217'
                    details.because 'GWT JUnitShell requires consistent Jetty 9.4.x'
                }
            }
            /*force 'org.eclipse.jetty:jetty-client:9.4.50.v20221201'
            force 'org.eclipse.jetty:jetty-http:9.4.50.v20221201'
            force 'org.eclipse.jetty:jetty-io:9.4.50.v20221201'
            force 'org.eclipse.jetty:jetty-util:9.4.50.v20221201'
            force 'org.eclipse.jetty.http2:http2-common:9.4.50.v20221201'
            force 'org.eclipse.jetty.http2:http2-client:9.4.50.v20221201'
            force 'org.eclipse.jetty.http2:http2-http-client-transport:9.4.50.v20221201'*/
        }
    }

    setupCompile {
        extendsFrom modulesCompile
    }

    // Default configuration of the java-library plugin
    // It corresponds to our compile configuration, that's why we have to use extendsFrom here
    setupImplementation {
        extendsFrom setupCompile
    }
}

// import dependencies
apply from: 'dependencies.gradle'
if (project.hasProperty('external_directories')){
    dependencies{
        moduleDeps fileTree(dir: external_directories).matching { include '**/lib/*.jar' }
        moduleDeps fileTree(dir: external_directories).matching { include '**/libext/*.jar' }
    }
}

eclipse.classpath.file {
    whenMerged { classpath ->
        classpath.entries.each {entry ->
            if ((entry.kind == 'src') && (entry.path.contains('gwt'))){
                entry.entryAttributes['test'] = 'true'
            }
            if (entry.kind == 'src' && entry.path == 'src') {
                entry.output='bin/main'
                entry.entryAttributes['test'] = 'false'
            }
        }
    }
}

eclipse.classpath.plusConfigurations = configurations.findAll { it.name.endsWith('Compile') }

eclipse.classpath.downloadSources=true

wrapper {
    gradleVersion = '7.5.1'
}

tasks.register('copyDeps', Copy) {
    from configurations.distribution
    into layout.buildDirectory.dir("deps")
}

tasks.register('copyCompileDeps', Copy) {
    from configurations.compile
    into layout.buildDirectory.dir("deps")
}

// Task from the java plugin
jar {
    manifest {
        attributes 'Implementation-Title': 'Alkacon OpenCms',
        'Implementation-Version': archiveVersion,
        'Build-Time': new java.util.Date().format("yyyy-MM-dd HH:mm:ss"),
        'OpenCms-Localization': 'en'
    }
    archiveBaseName = 'opencms-core'
    archiveFileName = 'opencms.jar'
    group = 'OpenCms core JARs'

    include 'org/opencms/**'
    include 'org/vaadin/risto/**'
    include 'com/**'
    include 'META-INF/**'
    exclude '**/package.html'
    exclude '**/overview.html'
    exclude '**/.gitignore'

    if (externalVersionProps.exists()){
        exclude 'org/opencms/main/version.properties'
        from (layout.buildDirectory.dir("..")){
            include 'version.properties'
            into 'org/opencms/main'
        }
    }

    metaInf {
        from("${projectDir}/webapp/WEB-INF/opencms.tld")
    }

    doLast {
        if (project.hasProperty('tomcat_update_target') && file(tomcat_update_target).exists()){
            println "copying ${layout.buildDirectory.dir("libs").get().file(archiveName).asFile} to ${tomcat_update_target}"
            copy {
                from  layout.buildDirectory.dir("libs").get().file(archiveName).asFile
                into tomcat_update_target
            }
        }
    }
}

// Task from the java plugin
javadoc {
    classpath += sourceSets.gwt.compileClasspath
    doLast {
        copy {
            from  "${projectDir}/doc/javadoc/logos"
            into layout.buildDirectory.dir("docs/javadoc/logos")
        }
    }

    project.configure(options) {
        memberLevel = org.gradle.external.javadoc.JavadocMemberLevel.PROTECTED
        charSet = "UTF-8"
        author="true"
        version="true"
        source= java_target_version
        linkSource="false"
        overview="${sourceSets.main.output.resourcesDir}/org/opencms/main/overview.html"
        docTitle="OpenCms Core API, version $ocmsVersion"
        windowTitle="OpenCms Core API, version $ocmsVersion"
        header = "<script type=\"text/javascript\"> if (window.location.href.indexOf(\"overview-frame\") == -1) { document.write(\"<a id=\\\"brandingLink\\\" target=\\\"_blank\\\" href=\\\"http://www.alkacon.com\\\"><img border=\\\"0\\\" id=\\\"brandingPic\\\" src=\\\"{@docRoot}/logos/Alkacon.svg\\\" /></a>\"); } else { document.write(\"<a id=\\\"brandingLink\\\" target=\\\"_blank\\\" href=\\\"http://www.opencms.com\\\"><img border=\\\"0\\\" id=\\\"brandingPic\\\" src=\\\"{@docRoot}/logos/OpenCms.svg\\\" /></a>\"); }</script>"
        use="true"
    }
}

tasks.register('javadocJar', Jar) {
    dependsOn javadoc
    archiveClassifier = 'javadoc'
    from layout.buildDirectory.dir("docs/javadoc")
    archiveBaseName = 'opencms-core'
}

tasks.register('sourcesJar', Jar) {
    from sourceSets.main.java.srcDirs
    archiveClassifier = 'sources'
    archiveBaseName = 'opencms-core'
}

tasks.register('gwtJar', Jar) {
    dependsOn jar
    from sourceSets.gwt.output
    from (sourceSets.gwt.java.srcDirs){ include '**/*.java' }
    from (sourceSets.main.java.srcDirs){
        include '**/shared/**'
        include '**/gwt/CmsRpcException.java'
        include '**/ade/detailpage/CmsDetailPageInfo.java'
        include '**/db/CmsResourceState.java'
        include '**/jsp/CmsContainerJsonKeys.java'
        include '**/util/CmsPair.java'
        include '**/util/CmsDefaultSet.java'
        include '**/xml/content/CmsXmlContentProperty.java'
        include '**/workplace/editors/CmsTinyMceToolbarHelper.java'
    }
    includeEmptyDirs = false
    archiveFileName = 'opencms-gwt.jar'
    archiveBaseName = 'opencms-gwt'
    exclude '**/.gitignore'
}

tasks.register('modulesJar', Jar) {
    from sourceSets.modules.output
    archiveFileName = 'opencms-modules.jar'
    archiveBaseName = 'opencms-modules'
    group = 'OpenCms core JARs'
    exclude '**/.gitignore'
}

tasks.register('javadocModules', Javadoc) {
    dependsOn jar
    doLast {
        copy {
            from  "${projectDir}/doc/javadoc/logos"
            into layout.buildDirectory.dir("docs/javadocModules/logos")
        }
    }

    project.configure(options) {
        memberLevel = org.gradle.external.javadoc.JavadocMemberLevel.PROTECTED
        charSet = "UTF-8"
        author="true"
        version="true"
        source= java_target_version
        linkSource="false"
        docTitle="OpenCms Workplace Modules API, version $ocmsVersion"
        windowTitle="OpenCms Workplace Modules API, version $ocmsVersion"
        header = "<script type=\"text/javascript\"> if (window.location.href.indexOf(\"overview-frame\") == -1) { document.write(\"<a id=\\\"brandingLink\\\" target=\\\"_blank\\\" href=\\\"http://www.alkacon.com\\\"><img border=\\\"0\\\" id=\\\"brandingPic\\\" src=\\\"{@docRoot}/logos/Alkacon.svg\\\" /></a>\"); } else { document.write(\"<a id=\\\"brandingLink\\\" target=\\\"_blank\\\" href=\\\"http://www.opencms.com\\\"><img border=\\\"0\\\" id=\\\"brandingPic\\\" src=\\\"{@docRoot}/logos/OpenCms.svg\\\" /></a>\"); }</script>"
    }
    source = sourceSets.modules.allJava
    classpath = project.sourceSets.modules.compileClasspath
    destinationDir = layout.buildDirectory.dir("docs/javadocModules").get().asFile
}

tasks.register('javadocJarModules', Jar) {
    dependsOn javadocModules
    archiveClassifier = 'javadoc'
    from layout.buildDirectory.dir("docs/javadocModules")
    archiveBaseName = 'opencms-modules'
}

tasks.register('sourcesJarModules', Jar) {
    from sourceSets.modules.java.srcDirs
    archiveClassifier = 'sources'
    archiveBaseName = 'opencms-modules'
}

tasks.register('javadocGwt', Javadoc) {
    dependsOn jar
    doLast {
        copy {
            from  "${projectDir}/doc/javadoc/logos"
            into layout.buildDirectory.dir("docs/javadocGwt/logos")
        }
    }

    project.configure(options) {
        memberLevel = org.gradle.external.javadoc.JavadocMemberLevel.PROTECTED
        charSet = "UTF-8"
        author="true"
        version="true"
        source= java_target_version
        linkSource="false"
        docTitle="OpenCms GWT Components API, version $ocmsVersion"
        windowTitle="OpenCms GWT Components API, version $ocmsVersion"
        header = "<script type=\"text/javascript\"> if (window.location.href.indexOf(\"overview-frame\") == -1) { document.write(\"<a id=\\\"brandingLink\\\" target=\\\"_blank\\\" href=\\\"http://www.alkacon.com\\\"><img border=\\\"0\\\" id=\\\"brandingPic\\\" src=\\\"{@docRoot}/logos/Alkacon.svg\\\" /></a>\"); } else { document.write(\"<a id=\\\"brandingLink\\\" target=\\\"_blank\\\" href=\\\"http://www.opencms.com\\\"><img border=\\\"0\\\" id=\\\"brandingPic\\\" src=\\\"{@docRoot}/logos/OpenCms.svg\\\" /></a>\"); }</script>"
    }
    source = sourceSets.gwt.allJava
    classpath = project.sourceSets.gwt.compileClasspath
    destinationDir = layout.buildDirectory.dir("docs/javadocGwt").get().asFile
}

tasks.register('javadocJarGwt', Jar) {
    dependsOn javadocGwt
    archiveClassifier = 'javadoc'
    from layout.buildDirectory.dir("docs/javadocGwt")
    archiveBaseName = 'opencms-gwt'
}

tasks.register('sourcesJarGwt', Jar) {
    from sourceSets.gwt.java.srcDirs
    from (sourceSets.main.java.srcDirs){
        include '**/shared/**'
        include '**/gwt/CmsRpcException.java'
        include '**/ade/detailpage/CmsDetailPageInfo.java'
        include '**/db/CmsResourceState.java'
        include '**/jsp/CmsContainerJsonKeys.java'
        include '**/util/CmsPair.java'
        include '**/util/CmsDefaultSet.java'
        include '**/xml/content/CmsXmlContentProperty.java'
        include '**/workplace/editors/CmsTinyMceToolbarHelper.java'
    }
    includeEmptyDirs = false
    archiveClassifier = 'sources'
    archiveBaseName = 'opencms-gwt'
}

tasks.register('workplaceTheme', JavaExec) {
    doFirst {
        println '======================================================'
        println "Building workplace theme"
        println "Generating ${layout.buildDirectory.dir("workplaceThemes/opencms/styles.css").get().asFile}"
        println '======================================================'
        def dir = layout.buildDirectory.dir("workplaceThemes/opencms").get().asFile
        if (dir.exists()){
            delete(dir)
        }
        dir.mkdirs()
    }

    mainClass = 'com.vaadin.sass.SassCompiler'

    classpath {
        [
            sourceSets.gwt.compileClasspath
        ]
    }


    args = [
        "$projectDir/webapp/workplaceThemes/VAADIN/themes/opencms/styles.scss",
        layout.buildDirectory.file("workplaceThemes/opencms/styles.css").get().asFile
    ]
    maxHeapSize = max_heap_size
}
tasks.register('opencmsFonts', JavaExec) {
    doFirst {
        println '======================================================'
        println "Building OpenCms fonts CSS"
        println "Generating ${layout.buildDirectory.dir("workplaceThemes/opencmsFonts/opencmsFonts.css").get().asFile}"
        println '======================================================'
        def dir = layout.buildDirectory.dir("workplaceThemes/opencmsFonts").get().asFile
        if (dir.exists()){
            delete(dir)
        }
        dir.mkdirs()
    }

    mainClass = 'com.vaadin.sass.SassCompiler'

    classpath {
        [
            sourceSets.gwt.compileClasspath
        ]
    }

    // opencmsFonts are generated into a different directory than the /opencms/styles.css
    // to avoid conflicts or dependencies between the build tasks 'workplaceTheme' and 'opencmsFonts'
    args = [
        "$projectDir/webapp/workplaceThemes/VAADIN/themes/opencms/opencmsFonts.scss",
        layout.buildDirectory.file("workplaceThemes/opencmsFonts/opencmsFonts.css").get().asFile
    ]
    maxHeapSize = max_heap_size
}


Properties gwtProps = new Properties()
gwtProps.load(new FileInputStream("$projectDir/src-gwt/gwt-modules.properties"))
project.ext.gwtModuleNames = gwtProps['gwtmodules']

tasks.register('resourcesJar', Jar) {
    dependsOn workplaceTheme, opencmsFonts
    doFirst {
        println '======================================================'
        println "Building Resources Jar"
        println '======================================================'
    }
    archiveBaseName = 'opencms-resources'
    archiveFileName = 'opencms-resources.jar'
    group = 'OpenCms core JARs'
    allModuleNames.each{ moduleName ->
        from ("${projectDir}/modules/${moduleName}/static"){
            into "OPENCMS"
        }
    }
    from ("${projectDir}/webapp/workplaceThemes"){
        exclude '**/*.scss'
    }
    from (layout.buildDirectory.dir("workplaceThemes/opencms")){
        into 'VAADIN/themes/opencms'
    }
    from (layout.buildDirectory.dir("workplaceThemes/opencmsFonts")){
        into 'VAADIN/themes/opencms'
    }
    gwtModuleNames.split(',').each{ gwtModule ->
        if (!'org.opencms.ui.WidgetSet'.equals(gwtModule)){
            from(layout.buildDirectory.dir("gwt/${gwtModule}")) {
                exclude '**/WEB-INF/**'
                into "OPENCMS/gwt"
            }
        }
    }

    from (layout.buildDirectory.dir("gwt/org.opencms.ui.WidgetSet")){
        include 'org.opencms.ui.WidgetSet/**'
        into 'VAADIN/widgetsets'
    }

    doLast {
        if (project.hasProperty('tomcat_update_target') && file(tomcat_update_target).exists()){
            println "copying ${layout.buildDirectory.dir("libs").get().file(archiveName).asFile} to ${tomcat_update_target}"
            copy {
                from  layout.buildDirectory.dir("libs").get().file(archiveName).asFile
                into tomcat_update_target
            }
        }
    }
}

// iterate gwt modules and create the required tasks
gwtModuleNames.split(',').each{ gwtModule ->
    tasks.register("gwt_${gwtModule}", JavaExec) {
        dependsOn gwtClasses
        ext.buildDir =  project.buildDir.toString()  +"/gwt/${gwtModule}"
        ext.extraDir =  project.buildDir.toString() + "/extra/${gwtModule}"
        inputs.files sourceSets.gwt.java.srcDirs
        inputs.dir sourceSets.gwt.output.resourcesDir
        outputs.dir buildDir

        // Workaround for incremental build (GRADLE-1483)
        outputs.upToDateSpec = new org.gradle.api.specs.AndSpec()

        doFirst {
            println '======================================================'
            println "Building GWT resources for ${gwtModule}"
            println '======================================================'
            // to clean the output directory, delete it first
            def dir = file(buildDir)
            if (dir.exists()){
                delete(dir)
            }
            dir.mkdirs()
        }

        mainClass = 'com.google.gwt.dev.Compiler'

        classpath {
            [
                // Java source core
                sourceSets.main.java.srcDirs,
                // Java source gwt
                sourceSets.gwt.java.srcDirs,
                // Java source modules
                sourceSets.modules.java.srcDirs,
                // Generated resources
                sourceSets.gwt.output.resourcesDir,
                // Generated classes
                sourceSets.gwt.java.classesDirectory,
                // Dependecies
                sourceSets.gwt.compileClasspath,
            ]
        }


        if (project.hasProperty('gwtDraft')) {
            println "Using GWT draft mode for module $gwtModule"
            args =
                    [
                        gwtModule,
                        // Your GWT module
                        '-war',
                        buildDir,
                        '-logLevel',
                        'ERROR',
                        '-localWorkers',
                        '2',
                        '-style',
                        'obfuscated',
                        '-extra',
                        extraDir,
                        '-draftCompile',
                        // Speeds up compile with 25%
                        '-setProperty',
                        'locale=en'
                    ]
        } else {
            args =
                    [
                        gwtModule,
                        // Your GWT module
                        '-war',
                        buildDir,
                        '-logLevel',
                        'ERROR',
                        '-localWorkers',
                        '2',
                        '-style',
                        'obfuscated',
                        '-extra',
                        extraDir,
                        '-strict'
                    ]
        }
        jvmArgs = [
            '-Dgwt.jjs.permutationWorkerFactory=com.google.gwt.dev.ThreadedPermutationWorkerFactory'
        ]

        maxHeapSize = max_heap_size
    }

    tasks.named('resourcesJar') {
        dependsOn tasks.named("gwt_${gwtModule}")
    }
}



tasks.register('setupJar', Jar) {
    dependsOn jar
    from sourceSets.setup.output
    archiveFileName = 'opencms-setup.jar'
    archiveBaseName = 'opencms-setup'
    group = 'OpenCms core JARs'
    exclude '**/.gitignore'
}

tasks.register('javadocSetup', Javadoc) {
    dependsOn jar
    source = sourceSets.setup.allJava
    classpath = project.sourceSets.setup.compileClasspath
    destinationDir = layout.buildDirectory.dir("docs/javadocSetup").get().asFile
    doLast {
        copy {
            from  "${projectDir}/doc/javadoc/logos"
            into layout.buildDirectory.dir("docs/javadocSetup/logos")
        }
    }

    project.configure(options) {
        memberLevel = org.gradle.external.javadoc.JavadocMemberLevel.PROTECTED
        charSet = "UTF-8"
        author="true"
        version="true"
        source= java_target_version
        linkSource="false"
        docTitle="OpenCms Setup API, version $ocmsVersion"
        windowTitle="OpenCms Setup API, version $ocmsVersion"
        header = "<script type=\"text/javascript\"> if (window.location.href.indexOf(\"overview-frame\") == -1) { document.write(\"<a id=\\\"brandingLink\\\" target=\\\"_blank\\\" href=\\\"http://www.alkacon.com\\\"><img border=\\\"0\\\" id=\\\"brandingPic\\\" src=\\\"{@docRoot}/logos/Alkacon.svg\\\" /></a>\"); } else { document.write(\"<a id=\\\"brandingLink\\\" target=\\\"_blank\\\" href=\\\"http://www.opencms.com\\\"><img border=\\\"0\\\" id=\\\"brandingPic\\\" src=\\\"{@docRoot}/logos/OpenCms.svg\\\" /></a>\"); }</script>"
    }
}

tasks.register('javadocJarSetup', Jar) {
    dependsOn javadocSetup
    archiveClassifier = 'javadoc'
    from layout.buildDirectory.dir("docs/javadocSetup")
    archiveBaseName = 'opencms-setup'
}

tasks.register('sourcesJarSetup', Jar) {
    from sourceSets.setup.java.srcDirs
    archiveClassifier = 'sources'
    archiveBaseName = 'opencms-setup'
}

tlddoc {
    source "${projectDir}/webapp/WEB-INF/opencms.tld"
}


tasks.register('tlddocZip', Zip) {
    dependsOn tlddoc
    archiveFileName = 'tld.zip'
    from (layout.buildDirectory.dir("docs/tlddoc")) {
        include '**/*'
    }
    destinationDirectory = layout.buildDirectory.dir("docs")
}

def preserveLibModules = ''
def localeModules = []

// iterate all available modules and create the required tasks
allModuleNames.each{ moduleName ->
    def modulePackages = moduleName
    def moduleFolder = file("${projectDir}/modules/${moduleName}")
    def propertyFile = file("${moduleFolder}/module.properties")
    def gwtRename = null
    def workplacelocalization=null;
    if (propertyFile.exists()){
        Properties moduleProperties= new Properties()
        moduleProperties.load(new FileInputStream(propertyFile))
        if (moduleProperties['workplacelocalization']!=null){
            workplacelocalization=moduleProperties['workplacelocalization']
        }
    }
    def manifestFile = file("${moduleFolder}/resources/manifest.xml")
    def moduleDependencies=[]
    def moduleVersion = version
    if (manifestFile.exists()){
        def parsedManifest= (new XmlParser()).parse("${moduleFolder}/resources/manifest.xml")
        parsedManifest.module[0].dependencies[0].dependency.each{ dep ->
            moduleDependencies.add(dep.@name)
        }
        moduleVersion = parsedManifest.module[0].version[0].text()
    }
    def staticFolder=file("${moduleFolder}/static")
    if (workplacelocalization!=null){
        localeModules.add("${moduleName}")
        preserveLibModules += "${moduleName},"
    }

    tasks.register("dist_$moduleName", Zip) {
        ext.moduleName = moduleName
        ext.moduleFolder = moduleFolder
        ext.dependencies = moduleDependencies

        if (project.hasProperty('noVersion')) {
            archiveVersion = ""
        } else {
            archiveVersion = moduleVersion
        }
        destinationDirectory = modulesDistsDir

        // excluding jars from modules, jars will be placed in the WEB-INF lib folder through the moduleDeps configuration
        from("${moduleFolder}/resources"){
            exclude '**/lib*/*.jar'
        }

        // TODO: set the module version to match the manifest.xml
        archiveBaseName = moduleName
        group = 'OpenCms module ZIPs'
        doFirst {
            println '======================================================'
            println "Building ZIP for $moduleName version $moduleVersion"
            println '======================================================'
        }
        doLast {
            if (project.hasProperty('module_copy_target') && file(module_copy_target).exists()){
                println "copying ${layout.buildDirectory.dir("modulesZip").get().file(archiveName).asFile} to ${module_copy_target}"
                copy {
                    from  layout.buildDirectory.dir("modulesZip").get().file(archiveName).asFile
                    into module_copy_target
                }
            }
        }
    }
    if (workplacelocalization != null){
        tasks.register("jar_$moduleName", Jar) {
            ext.moduleName = moduleName
            ext.workplacelocalization=workplacelocalization
            manifest {
                attributes 'Implementation-Title': 'Alkacon OpenCms', 'Implementation-Version': archiveVersion
                if (workplacelocalization!=null) {
                    attributes 'OpenCms-Localization': workplacelocalization
                }
            }
            from ("$moduleFolder/resources/system/workplace/locales/$workplacelocalization/messages")
            archiveFileName = moduleName+'.jar'
            archiveBaseName = moduleName
            group = 'OpenCms module JARs'
            exclude '**/.gitignore'
            doFirst{
                println '======================================================'
                println "Building ${moduleName}.jar including $modulePackages"
                println '======================================================'
            }

            doLast {
                if (project.hasProperty('tomcat_update_target') && file(tomcat_update_target).exists()){
                    println "copying ${layout.buildDirectory.dir("libs").get().file(archiveName).asFile} to ${tomcat_update_target}"
                    copy {
                        from  layout.buildDirectory.dir("libs").get().file(archiveName).asFile
                        into tomcat_update_target
                    }
                }
            }
        }
        tasks.named("dist_$moduleName") {
            dependsOn tasks.named("jar_$moduleName")
        }
    }
}

tasks.register('allModules') {
    dependsOn tasks.matching{ Task task -> task.name.startsWith('dist_')}
    doLast {
        println '======================================================'
        println 'Done building modules'
        println '======================================================'
    }
}

tasks.register('war', Zip) {
    dependsOn setupJar, resourcesJar, modulesJar, allModules

    if (hasExtModules) {
        dependsOn {
            ':extmodules:bindist'
        }
    }
    archiveFileName = 'opencms.war'
    archiveBaseName = 'opencms-webapp'
    archiveExtension = 'war'
    ext.localeModules=localeModules;

    from ("${projectDir}/webapp"){
        // exclude the database drivers
        exclude '**/setupdata/**/*.jar'
        exclude '**/updatedata/**'
        exclude '**/workplaceThemes/**'
        exclude '**/classes/META-INF/**'
        exclude '**/solr/**'
        exclude '**/spellcheck/**'
        exclude '**/*.html'
        exclude '**/*.properties'
        exclude '**/*.txt'
        exclude '**/*.xml'
    }

    // copy SOLR config files separately to avoid the replace filter corrupting them
    from ("${projectDir}/webapp/WEB-INF/solr"){
        into '/WEB-INF/solr/'
    }

    from ("${projectDir}/webapp"){
        exclude '**/updatedata/**'
        exclude '**/workplaceThemes/**'
        exclude '**/solr/**'
        exclude '**/spellcheck/**'
        exclude 'WEB-INF/sun-jaxws.xml'
        include '**/*.html'
        include '**/*.properties'
        include '**/*.txt'
        include '**/*.xml'
        filter(ReplaceTokens, tokens: [
            OPENCMS_VERSION_NUMBER: project.version,
            OPENCMS_VERSION: product_name+' '+ project.version,
            DRIVERS_VFS: drivers_vfs,
            DRIVERS_PROJECT: drivers_project,
            DRIVERS_USER: drivers_user,
            DRIVERS_HISTORY: drivers_history,
            DRIVERS_CONFIGURATION: drivers_configuration,
            DRIVERS_SUBSCRIPTION: drivers_subscription,
            ADDITIONAL_DB_POOLS: db_additional_pools,
            OPENCMS_CONFIGURATION: opencms_configuration,
            RUNTIME_INFO: system_runtimeinfo,
            COMMENT_UPDATER_START: '',
            COMMENT_UPDATER_END: '',
            COMMENT_WAR_START: '<!--',
            COMMENT_WAR_END: '-->'
        ])
    }

    from (layout.buildDirectory.dir("libs")) {
        include '*.jar'
        exclude 'opencms-gwt*.jar'
        exclude 'opencms-test*.jar'
        exclude '*-sources.jar'
        exclude '*-javadoc.jar'
        into '/WEB-INF/lib'
    }

    into ('/WEB-INF/lib') { from configurations.distribution }
    into ('/WEB-INF/lib') { from configurations.moduleDeps }
    into ('/WEB-INF/lib/apis') { from configurations.usedApis }

    fileTree('webapp/WEB-INF/setupdata/database'){ include '**/*.jar'}.each {File driverJar ->
        // copy the database drivers into the lib folder
        from (driverJar.path) { into '/WEB-INF/lib' }
    }

    from (modulesDistsDir) {
        into '/WEB-INF/packages/modules'
        localeModules.each{ localeModule ->
            exclude "${localeModule}*.zip"
        }
    }

    from("${projectDir}/lib/jni") { into "/WEB-INF/lib/jni" }

    if (hasExtModules) {
        // Note that the module deps do not need to be copied
        // since they are contained in configurations.moduleDeps
        def extModulesDir = extModulesProject.layout.buildDirectory.dir("modules").get().asFile
        from ("${extModulesDir}/libs") {
            include '*.jar'
            into '/WEB-INF/lib'
        }
        from ("${extModulesDir}/modulesZip") {
            into '/WEB-INF/packages/modules'
        }
    }
}

tasks.register('updater', Zip) {
    dependsOn setupJar, resourcesJar, modulesJar, allModules
    if (hasExtModules) {
        // without this declaration, Gradle 8 complains about implicit dependencies
        dependsOn {
            ':extmodules:bindist'
            ':extmodules:copyProjectProps'
        }
    }

    dependsOn {
        tasks.matching{dist_task -> dist_task.name.startsWith('dist_')}
    }

    archiveBaseName = 'opencms-upgrade-to'
    ext.preserveLibModules = preserveLibModules

    // adds empty JAR files for all deprecated or updated libs
    Properties buildProps = new Properties()
    buildProps.load(new FileInputStream("${projectDir}/build-default.properties"))
    buildProps['updater.jars.remove'].split(',').each{ jar ->
        from("${projectDir}/webapp/WEB-INF/updatedata/empty.jar"){
            into '/WEB-INF/lib'
            rename('empty\\.jar', jar)
        }
    }

    // only process the text files with the ReplaceTokens filter, copy everything else in a second from clause
    from ("${projectDir}/webapp"){
        include 'WEB-INF/updatedata/**/*.ori'
        include 'WEB-INF/updatedata/**/*.html'
        include 'WEB-INF/updatedata/**/*.xml'
        include 'WEB-INF/updatedata/**/*.txt'
        include 'WEB-INF/updatedata/**/*.jsp'
        exclude 'WEB-INF/updatedata/config/opencms.xml'
        exclude 'WEB-INF/updatedata/readme.txt'
        exclude 'WEB-INF/updatedata/empty.jar'
        filter(ReplaceTokens, tokens: [
            OPENCMS_VERSION_NUMBER: project.version,
            OPENCMS_VERSION: product_name+' '+ project.version,
            PRESERVE_LIB_MODULES: preserveLibModules
        ])
    }

    from ("${projectDir}/webapp"){
        include 'WEB-INF/updatedata/**'
        exclude 'WEB-INF/updatedata/**/*.ori'
        exclude 'WEB-INF/updatedata/**/*.html'
        exclude 'WEB-INF/updatedata/**/*.xml'
        exclude 'WEB-INF/updatedata/**/*.txt'
        exclude 'WEB-INF/updatedata/**/*.jsp'
        exclude 'WEB-INF/updatedata/config/opencms.xml'
        exclude 'WEB-INF/updatedata/readme.txt'
        exclude 'WEB-INF/updatedata/empty.jar'
    }

    from ("${projectDir}/webapp/WEB-INF/classes/log4j2.xml") {
        into '/WEB-INF/classes'
    }

    from ("${projectDir}/webapp/WEB-INF/updatedata/config/opencms.xml") {
        into '/WEB-INF/config'
    }

    from("${projectDir}/webapp/WEB-INF/config/opencms-workplace.xml"){
        into '/WEB-INF/config/defaults'
    }

    from("${projectDir}/webapp/WEB-INF/config/opencms-vfs.xml"){
        into '/WEB-INF/config/defaults'
    }

    from("${projectDir}/webapp/WEB-INF/config/opencms-importexport.xml"){
        into '/WEB-INF/config/defaults'
    }

    from("${projectDir}/webapp/WEB-INF/config/opencms-system.xml"){
        into '/WEB-INF/config/defaults'
    }

    from("${projectDir}/webapp/WEB-INF/config/opencms-search.xml"){
        into '/WEB-INF/config/defaults'
    }

    from ("${projectDir}/webapp/WEB-INF/solr"){
        into '/WEB-INF/solr-update/'
        include '*'
        include '**/*'
    }

    from ("${projectDir}/webapp/WEB-INF/updatedata/readme.txt"){
        filter(ReplaceTokens, tokens: [
            OPENCMS_VERSION_NUMBER: project.version,
            OPENCMS_VERSION: product_name+' '+ project.version
        ])
    }
    from ("${projectDir}/webapp/WEB-INF"){
        into '/WEB-INF'
        include 'opencms.tld'
        exclude 'web.xml'
        include 'cmsshell.sh'
        include 'classes/META-INF/persistence.xml'
        include 'classes/ehcache.xml'
        include 'classes/repository.properties'
        include 'sun-jaxws.xml'
        include 'spellcheck/**'
        include 'git-scripts/**'
    }
    from ("${projectDir}/webapp/WEB-INF"){
        into '/WEB-INF'
        include 'web.xml'
        filter(ReplaceTokens, tokens: [
            COMMENT_UPDATER_START: '<!-- ',
            COMMENT_UPDATER_END: '-->',
            COMMENT_WAR_START: '',
            COMMENT_WAR_END: ''
        ])
    }
    from ("${projectDir}/webapp/resources"){
        into '/resources'
        include '*'
        include '**/*'
    }
    from (layout.buildDirectory.dir("libs")) {
        include '*.jar'
        exclude 'opencms-test*.jar'
        exclude 'opencms-gwt*.jar'
        exclude '*-sources.jar'
        exclude '*-javadoc.jar'
        into '/WEB-INF/lib'
    }
    into ('/WEB-INF/lib') {
        from configurations.distribution
    }

    from (modulesDistsDir) {
        into '/WEB-INF/updatedata/modules'
        localeModules.each{ localeModule ->
            exclude "${localeModule}*.zip"
        }
        exclude "*mercury*.zip"
    }

    fileTree('webapp/WEB-INF/setupdata/database'){ include '**/*.jar'}.each {File driverJar ->
        // copy the database drivers into the lib folder
        from (driverJar.path) { into '/WEB-INF/lib' }
    }
}

tasks.register('bindist', Zip) {
    dependsOn war
    archiveBaseName = 'opencms'
    from layout.buildDirectory.file("distributions/opencms.war").get().asFile
    from(projectDir) {
        include 'INSTALL.md'
        include 'LICENSE'
        include 'README.md'
        include 'history.txt'
        filter(ReplaceTokens, tokens: [
            OPENCMS_VERSION_NUMBER: project.version,
            OPENCMS_VERSION: product_name+' '+ project.version
        ])
    }
}


// Shared configuration for all test tasks
tasks.withType(Test).configureEach {
    maxHeapSize = "2000m"
    useJUnit()
    scanForTestClasses = false
    testLogging.showStandardStreams = true
    ignoreFailures = true
}

def coreTestConfig = {
    testClassesDirs = files(sourceSets.test.java.classesDirectory)
    systemProperties['test.data.path'] = "${projectDir}/test/data"
    systemProperties['test.webapp.path'] = "${projectDir}/webapp"
    systemProperties['test.project.path'] = "${projectDir}"
    systemProperties['test.build.folder'] = sourceSets.test.output.resourcesDir
    inputs.dir "${projectDir}/test/data"
    inputs.dir "${projectDir}/webapp"
}

test {
    configure coreTestConfig
    description "Runs the complete test suite 'org.opencms.test.AllTests'."

    filter.includeTestsMatching("org.opencms.test.AllTests")
}

tasks.register('testSingle', Test) {
    description "Runs a specified test case. Equivalent to standard 'test' task. \n" +
                "NOTE: Usage of legacy '-PtestCaseToRun' property is DEPRECATED. Use standard '--tests' filtering instead. \n" +
                "Conflict Resolution: If both '-PtestCaseToRun' and '--tests' are defined, standard '--tests' takes precedence. \n" +
                "Default: Runs TestCmsSystemInfo test case if no filters are provided."
    group 'verification'
    configure coreTestConfig

    doFirst{
        logger.info("Test filter configuration - commandLineIncludePatterns: ${filter.commandLineIncludePatterns}, includePatterns: ${filter.includePatterns}")

        boolean hasExplicit = !filter.commandLineIncludePatterns.empty || !filter.includePatterns.empty
        
        // Backward compatibility: Check for -PtestCaseToRun property
        if (project.hasProperty('testCaseToRun')) {
             if (hasExplicit) {
                 logger.warn("WARNING: Both -PtestCaseToRun and --tests filters are present. Using standard Gradle filters and ignoring legacy property.")
             } else {
                 def legacyTestInfo = project.property('testCaseToRun')
                 logger.warn("DEPRECATION WARNING: The 'testCaseToRun' property is deprecated. Please use standard Gradle filtering: ./gradlew testSingle --tests ${legacyTestInfo}")
                 filter.includeTestsMatching "${legacyTestInfo}*"
                 hasExplicit = true
             }
        }

        logger.debug("hasExplicitTestSelection: ${hasExplicit}")

        if (!hasExplicit) {
            logger.lifecycle("No specific tests requested, applying default filter: org.opencms.main.TestCmsSystemInfo*")
            filter.includeTestsMatching "org.opencms.main.TestCmsSystemInfo*"
        }
    }
}

tasks.register('testJar', Jar) {
    dependsOn compileTestJava
    from sourceSets.test.output
    archiveBaseName = 'opencms-test'
    exclude '**/.gitignore'
    exclude '**/*.java'
}

tasks.register('javadocTest', Javadoc) {
    dependsOn jar
    source = sourceSets.test.allJava
    classpath = project.sourceSets.test.compileClasspath
    destinationDir = layout.buildDirectory.dir("docs/javadocTest").get().asFile
}

tasks.register('javadocJarTest', Jar) {
    dependsOn javadocTest
    archiveClassifier = 'javadoc'
    from layout.buildDirectory.dir("docs/javadocTest")
    archiveBaseName = 'opencms-test'
}

tasks.register('sourcesJarTest', Jar) {
    from sourceSets.test.java.srcDirs
    archiveClassifier = 'sources'
    archiveBaseName = 'opencms-test'
}


tasks.register('testGwt', Test) {
    dependsOn compileTestGwtJava
    classpath=sourceSets.testGwt.runtimeClasspath
    classpath += files("${projectDir}/src")
    classpath += files("${projectDir}/src-gwt")
    classpath += files("${projectDir}/test-gwt")
    useJUnit()
    filter {
        includeTestsMatching 'org.opencms.client.test.AllTests'
    }
    scanForTestClasses = false
    testClassesDirs = files(sourceSets.testGwt.java.classesDirectory)
    systemProperties['gwt.args'] = "-logLevel WARN -setProperty locale=en"
    systemProperties['java.awt.headless'] = "true"
    maxHeapSize = max_heap_size
    testLogging.showStandardStreams = true
    ignoreFailures = true
}

artifacts {
    archives sourcesJar

    if (gradle.startParameter.taskNames.contains("uploadArchives")) {
        // do not include the war if only running the install task, it takes ages to build
        archives war
        archives resourcesJar
    }

    archives setupJar
    archives sourcesJarSetup

    archives modulesJar
    archives sourcesJarModules

    archives gwtJar
    archives sourcesJarGwt

    archives testJar
    archives sourcesJarTest

    tasks.each { task ->
        if (task.name.startsWith("jar_org.opencms.")){
            def moduleName=task.archiveBaseName
            archives task
            if (tasks.hasProperty("sourcesJar_$moduleName")) {
                archives tasks["sourcesJar_$moduleName"]
            }
        }
    }
    // in case the property 'skip_javadoc' is set to 'true', javadoc generation is skipped - this is supposed to speed up build time for CI
    if (addJavadoc) {
        archives javadocJar
        archives javadocJarSetup
        archives javadocJarModules
        archives javadocJarGwt
        archives javadocJarTest
        tasks.each { task ->
            if (task.name.startsWith("jar_org.opencms.")) {
                def moduleName=task.archiveBaseName
                if (tasks.hasProperty("javadocJar_$moduleName")) {
                    archives tasks["javadocJar_$moduleName"]
                }
            }
        }
    }
}


publishing {
    publications { pubs ->
        core(MavenPublication) {
            from components.java
            artifact sourcesJar
            if (addJavadoc) artifact javadocJar
            pom {
                name = product_name
                description = product_description
                packaging = 'jar'
                groupId = 'org.opencms'
                url = 'http://www.opencms.org'
                scm {
                    url = 'scm:git@github.com:alkacon/opencms-core.git'
                    connection = 'scm:git@github.com:alkacon/opencms-core.git'
                    developerConnection = 'scm:git@github.com:alkacon/opencms-core.git'
                }
                licenses {
                    license {
                        name = 'GNU Lesser General Public License'
                        url = 'http://www.gnu.org/licenses/lgpl.html'
                        distribution = 'repo'
                    }
                }
                organization {
                    name = 'Alkacon Software'
                    url = 'https://www.alkacon.com'
                }
                developers {
                    developer {
                        name = 'Alkacon Software'
                        url = 'https://www.alkacon.com'
                    }
                }
                withXml {
                    // Update dependencies with resolved versions
                    def hasDependencies = !asNode().dependencies.isEmpty()
                    if (hasDependencies) {
                        // for some reason Gradle incorrectly sets the scope to 'runtime' for some dependencies, so we fix it
                        // (if we didn't do this, the dependencies would be missing in dependent projects)
                        asNode().dependencies.'*'.each() { dep ->
                            if (dep.scope.text() == 'runtime' && dep.artifactId.text() in [
                                        'javax.servlet-api',
                                        'javax.servlet.jsp-api'
                                    ]) {
                                println("Correcting scope for dependency ${dep.artifactId.text()}")
                                dep.scope.first().setValue('compile')
                            }
                        }

                        // add additional repositories to search artifacts in
                        def repositoriesNode = asNode().appendNode('repositories')
                        def respositoryNode = repositoriesNode.appendNode('repository')
                        respositoryNode.appendNode('id', 'vaadin-addons');
                        respositoryNode.appendNode('url', 'https://maven.vaadin.com/vaadin-addons');
                        respositoryNode = repositoriesNode.appendNode('repository')
                        respositoryNode.appendNode('id', 'restlet');
                        respositoryNode.appendNode('url', 'https://maven.restlet.org');
                    }
                }
            }
        }
        /*versionMapping {
         usage('api') {
         fromResolutionOf(configurations.distribution)
         }
         usage('runtime') {
         fromResolutionOf(configurations.distribution)
         }
         }*/
        def furtherPubs = [
            "setup" : [
                "artifacts" : addJavadoc ? [
                    setupJar,
                    sourcesJarSetup,
                    javadocJarSetup
                ] : [setupJar, sourcesJarSetup]
            ],
            "modules" : [
                "artifacts" : addJavadoc ? [
                    modulesJar,
                    sourcesJarModules,
                    javadocJarModules
                ] : [
                    modulesJar,
                    sourcesJarModules
                ]
            ],
            "gwt" : [
                "artifacts" : addJavadoc ? [
                    gwtJar,
                    sourcesJarGwt,
                    javadocJarGwt
                ] : [gwtJar, sourcesJarGwt]
            ],
            "test" : [
                "artifacts" : addJavadoc ? [
                    testJar,
                    sourcesJarTest,
                    javadocJarTest
                ] : [testJar, sourcesJarTest]
            ]
        ]
        furtherPubs.each { pub ->
            pubs.create(pub.key, MavenPublication) {
                pub.value.artifacts.each { art ->
                    artifact art
                }
                pom {
                    artifactId = "opencms-${pub.key}"
                    name = product_name
                    description = product_description
                    packaging = 'jar'
                    groupId = 'org.opencms'
                    url = 'http://www.opencms.org'
                    scm {
                        url = 'scm:git@github.com:alkacon/opencms-core.git'
                        connection = 'scm:git@github.com:alkacon/opencms-core.git'
                        developerConnection = 'scm:git@github.com:alkacon/opencms-core.git'
                    }
                    licenses {
                        license {
                            name = 'GNU Lesser General Public License'
                            url = 'http://www.gnu.org/licenses/lgpl.html'
                            distribution = 'repo'
                        }
                    }
                    organization {
                        name = 'Alkacon Software'
                        url = 'https://www.alkacon.com'
                    }
                    developers {
                        developer {
                            name = 'Alkacon Software'
                            url = 'https://www.alkacon.com'
                        }
                    }

                    if (pub.key == 'gwt') {
                        withXml { xml ->
                            def deps = xml.asNode().appendNode('dependencies');
                            def dependenciesGwt=project.configurations.gwtCompile.dependencies
                            dependenciesGwt.each { dep ->
                                if (dep instanceof ExternalModuleDependency) {
                                    def dependency = deps.appendNode('dependency')
                                    dependency.appendNode('groupId', dep.group)
                                    dependency.appendNode('artifactId', dep.name)
                                    dependency.appendNode('version', dep.version)
                                }
                            }
                            def dependencyNode = deps.appendNode('dependency')
                            dependencyNode.appendNode('artifactId','opencms-core')
                            dependencyNode.appendNode('groupId','org.opencms')
                            dependencyNode.appendNode('version',version)
                        }
                    } else {
                        withXml {
                            def hasDependencies = !asNode().dependencies.isEmpty()
                            if (hasDependencies) {
                                asNode().removeChild(asNode().dependencies)
                            }
                            def dependenciesNode = asNode().appendNode('dependencies')
                            def dependencyNode = dependenciesNode.appendNode('dependency')
                            dependencyNode.appendNode('artifactId','opencms-core')
                            dependencyNode.appendNode('groupId','org.opencms')
                            dependencyNode.appendNode('version',version)
                        }
                    }
                }
            }
        }
        if (gradle.startParameter.taskNames.contains("uploadArchives")) {
            webapp(MavenPublication) {
                artifact war
                pom {
                    artifactId 'opencms-webapp'
                    name = product_name
                    description = product_description
                    packaging 'war'
                    groupId 'org.opencms'
                    url = 'http://www.opencms.org'
                    scm {
                        url = 'scm:git@github.com:alkacon/opencms-core.git'
                        connection = 'scm:git@github.com:alkacon/opencms-core.git'
                        developerConnection = 'scm:git@github.com:alkacon/opencms-core.git'
                    }
                    licenses {
                        license {
                            name = 'GNU Lesser General Public License'
                            url = 'http://www.gnu.org/licenses/lgpl.html'
                            distribution = 'repo'
                        }
                    }
                    organization {
                        name = 'Alkacon Software'
                        url = 'https://www.alkacon.com'
                    }
                    developers {
                        developer {
                            name = 'Alkacon Software'
                            url = 'https://www.alkacon.com'
                        }
                    }
                }
            }
            pubs.each { pub ->
                signing.sign pub
            }
        }
    }
}


// add it to keep the old task names
tasks.register('install') {
    dependsOn publishToMavenLocal
    doFirst {
        println "Installing artifacts for version $version"
    }
}

tasks.register('uploadArchives') { // dependency tasks are set dynamically via afterEvaluate
    doFirst {
        println "Upload artifacts for version $version"
    }
}


// fixed issue with libraries containing both .java and .class files
tasks.withType(JavaCompile) {
    options.sourcepath=files()
    options.encoding='UTF-8'
    options.incremental = true
}
tasks.withType(Javadoc) {
    options.addStringOption("sourcepath", "")
    if (JavaVersion.current().isJava8Compatible()) {
        options.addStringOption("Xdoclint:none", "-quiet")
        options.addBooleanOption("-allow-script-in-comments",true);
    }
    doLast {
        def searchScript = new File(destinationDir.getAbsolutePath() + '/search.js')
        searchScript.append "getURLPrefix = function(ui) { return ''; };"
    }
}
// all tasks implementing the CopySpec (Copy,Jar,Zip,...) should fail, in case they generate duplicate files
tasks.withType(CopySpec) {
    duplicatesStrategy = 'fail'
}


// The Gradle module metadata generation ignores the non-transitiveness of our dependencies, just as the POM generation normally does.
// This leads to conflicts / build errors in dependent projects.
// We already manually fix it for the POM, but I don't know how to fix it for the module metadata generation.
// So just disable the module metadata - there is no benefit from it right now.
tasks.withType(GenerateModuleMetadata) {
    enabled = false
}

afterEvaluate {
    def uploadArchivesDeps = [tasks.findByName("publishToSonatype"), tasks.findByName("closeSonatypeStagingRepository")]
    tasks.findByName("uploadArchives").dependsOn(uploadArchivesDeps)
}