Fission/build.gradle.kts at main · groundbreakingmc/Fission · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
plugins {
    id("java")
    id("me.champeau.jmh") version "0.7.3"
    id("maven-publish")
}

group = "com.github.groundbreakingmc"
version = "1.0.0"

repositories {
    mavenCentral()
}

dependencies {
    // ANNOTATIONS

    // https://github.com/JetBrains/java-annotations
    implementation("org.jetbrains:annotations:26.0.2")

    // TESTS

    testImplementation(platform("org.junit:junit-bom:5.9.1"))
    testImplementation("org.junit.jupiter:junit-jupiter")

    // https://mvnrepository.com/artifact/org.openjdk.jmh/jmh-core
    testImplementation("org.openjdk.jmh:jmh-core:1.37")
    // https://mvnrepository.com/artifact/org.openjdk.jmh/jmh-generator-annprocess
    testImplementation("org.openjdk.jmh:jmh-generator-annprocess:1.37")
}

tasks.register<Jar>("sourcesJar") {
    from(sourceSets.main.get().allJava)
    archiveClassifier.set("sources")
}

tasks.register<Jar>("javadocJar") {
    from(tasks.javadoc)
    archiveClassifier.set("javadoc")
}

publishing {
    publications {
        create<MavenPublication>("mavenJava") {
            from(components["java"])
            artifact(tasks["sourcesJar"])
            artifact(tasks["javadocJar"])

            pom {
                name = "Fission"
                description = "A high-performance, zero-dependency library designed for blazing-fast file reading and character stream processing. Fission outperforms standard Java I/O by 20-100x in parsing operations while providing a clean, exception-free API."
                url = "https://github.com/groundbreakingmc/Fission"

                licenses {
                    license {
                        name = "The Apache License, Version 2.0"
                        url = "https://github.com/groundbreakingmc/Fission?tab=Apache-2.0-1-ov-file"
                    }
                }

                developers {
                    developer {
                        id = "GroundbreakingMC"
                        name = "Victor"
                    }
                }

                scm {
                    connection = "scm:git:git://github.com/groundbreakingmc/Fission.git"
                    developerConnection = "scm:git:ssh://git@github.com:groundbreakingmc/Fission.git"
                    url = "https://github.com/groundbreakingmc/Fission"
                }
            }
        }
    }
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

tasks {
    test {
        useJUnitPlatform()
    }
    withType<JavaCompile> {
        options.release = 17
    }
    withType<Jar> {
        manifest {
            attributes["Implementation-Title"] = project.name
            attributes["Implementation-Version"] = project.version
        }
    }
    withType<Javadoc> {
        options {
            encoding = "UTF-8"
            (this as StandardJavadocDocletOptions).addStringOption("Xdoclint:none", "-quiet")
        }
    }
}