Add force locale

Author: vtm9

apps/codebattle/lib/codebattle_web/plugs/locale.ex

@@ -10,18 +10,30 @@ defmodule CodebattleWeb.Plugs.Locale do
   def init(_opts), do: nil
 
   def call(conn, _opts) do
-    default_locale = Application.get_env(:codebattle, :default_locale, "en")
-
-    locale =
-      case conn.assigns[:current_user] do
-        %{locale: locale} when locale in @valid_locales -> locale
-        _ -> default_locale
-      end
+    locale = get_forced_locale() || get_user_locale(conn) || get_default_locale()
 
     Gettext.put_locale(CodebattleWeb.Gettext, locale)
 
     conn
     |> put_gon(locale: locale)
     |> put_session(:locale, locale)
   end
+
+  defp get_forced_locale do
+    case Application.get_env(:codebattle, :force_locale) do
+      locale when locale in @valid_locales -> locale
+      _ -> nil
+    end
+  end
+
+  defp get_user_locale(conn) do
+    case conn.assigns[:current_user] do
+      %{locale: locale} when locale in @valid_locales -> locale
+      _ -> nil
+    end
+  end
+
+  defp get_default_locale do
+    Application.get_env(:codebattle, :default_locale, "en")
+  end
 end

apps/codebattle/test/codebattle_web/controllers/locale_test.exs

@@ -1,5 +1,15 @@
 defmodule CodebattleWeb.LocaleTest do
-  use CodebattleWeb.ConnCase, async: true
+  use CodebattleWeb.ConnCase, async: false
+
+  setup do
+    previous_force_locale = Application.get_env(:codebattle, :force_locale)
+
+    on_exit(fn ->
+      Application.put_env(:codebattle, :force_locale, previous_force_locale)
+    end)
+
+    :ok
+  end
 
   test "uses current user locale when available", %{conn: conn} do
     user = insert(:user, locale: "ru")
@@ -28,4 +38,28 @@ defmodule CodebattleWeb.LocaleTest do
 
     assert get_session(conn, :locale) == "en"
   end
+
+  test "uses forced locale over current user locale", %{conn: conn} do
+    Application.put_env(:codebattle, :force_locale, "ru")
+    user = insert(:user, locale: "en")
+
+    conn =
+      conn
+      |> put_session(:user_id, user.id)
+      |> get(Routes.root_path(conn, :index))
+
+    assert get_session(conn, :locale) == "ru"
+  end
+
+  test "ignores unsupported forced locale", %{conn: conn} do
+    Application.put_env(:codebattle, :force_locale, "de")
+    user = insert(:user, locale: "ru")
+
+    conn =
+      conn
+      |> put_session(:user_id, user.id)
+      |> get(Routes.root_path(conn, :index))
+
+    assert get_session(conn, :locale) == "ru"
+  end
 end

config/config.exs

@@ -87,6 +87,7 @@ config :codebattle, dev_sign_in: true
 # General application configuration
 config :codebattle, ecto_repos: [Codebattle.Repo]
 config :codebattle, fake_html_to_image: false
+config :codebattle, force_locale: System.get_env("CODEBATTLE_FORCE_LOCALE")
 config :codebattle, free_users_redirect_url: "/"
 config :codebattle, freeze_time: false
 config :codebattle, html_debug_mode: true

config/runtime.exs

@@ -183,6 +183,7 @@ config :codebattle, default_locale: System.get_env("CODEBATTLE_DEFAULT_LOCALE",
 config :codebattle,
   deployed_at: System.get_env("DEPLOYED_AT") || Calendar.strftime(DateTime.utc_now(), "%c")
 
+config :codebattle, force_locale: System.get_env("CODEBATTLE_FORCE_LOCALE")
 config :codebattle, free_users_redirect_url: System.get_env("CODEBATTLE_FREE_USERS_REDIRECT_URL", "/")
 config :codebattle, host: codebattle_host
 config :codebattle, k8s_namespace: System.get_env("KUBERNETES_NAMESPACE", "default")