Is it possible to call C functions?

[ghost]

Can you give me an example? e.g: calling Windows API MessageBoxA function?

[mertcandav]

Hi.

Of course, a MessageBoxA example written in Jule 0.1.3:

use integ "std/jule/integrated"
use "std/sys"

// Bind Windows API
cpp type UINT: u32
cpp type HWND: *unsafe
cpp unsafe fn MessageBoxA(hWnd: cpp.HWND, lpText: *integ::Char, lpCaption: *integ::Char, uType: cpp.UINT): integ::Int

// Wrap Windows API with the safe Jule code
const MB_ABORTRETRYIGNORE = 0x00000002
const MB_CANCELTRYCONTINUE = 0x00000006
const MB_HELP = 0x00004000
const MB_OK = 0x00000000
const MB_OKCANCEL = 0x00000001
const MB_RETRYCANCEL = 0x00000005
const MB_YESNO = 0x00000004
const MB_YESNOCANCEL = 0x00000003
const MB_ICONINFORMATION = 0x00000040

const NoOwnerWindow = uintptr(0)

fn MessageBox(h: uintptr, text: str, caption: str, typ: u32)!: int {
	textb := integ::StrToBytes(text)
	captionb := integ::StrToBytes(caption)
	r := unsafe { cpp.MessageBoxA(cpp.HWND(h), (*integ::Char)(&textb[0]), (*integ::Char)(&captionb[0]), cpp.UINT(typ)) }
	if r == 0 {
		error(sys::GetLastError())
	}
	ret unsafe { int(r) }
}

fn main() {
	MessageBox(NoOwnerWindow, "Hello World", "Example Window", MB_OK|MB_ICONINFORMATION)!
}

The above code binds the MessageBoxA function and its related types to the source code, as they are not part of the Jule standard library. It then defines the MessageBox wrapper function to provide a safer usage. This function primarily converts types into the required Windows API types and transforms text data using the StrToBytes function, ensuring Jule strings are compatible with NULL-terminated C strings. If an error occurs, an exception is thrown. The exception is the value returned by sys::GetLastError, which internally uses the Windows API GetLastError function.