vim-ledger/Justfile at master · ledger/vim-ledger · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
git := which('git')
just := just_executable()
nvim := which('nvim')
vim := which('vim')

set unstable := true

ledger := "ledger"

[default]
[private]
@list:
    {{ just }} --list --unsorted

[no-cd]
preview-vim *ARGS: (preview vim + ' --clean' ARGS)

[no-cd]
preview-nvim *ARGS: (preview nvim + ' --clean' ARGS)

[no-cd]
[private]
preview vimcmd *ARGS:
    {{ vimcmd }} \
        -c 'let g:ledger_bin = "{{ ledger }}"' \
        -c {{ quote("let &runtimepath=\"" + justfile_directory() + ",\" . &runtimepath") }} \
        -c 'filetype detect' \
        {{ ARGS }}

[no-cd]
check-vim *ARGS: (check vim + ' --clean -N' ARGS)

[no-cd]
check-nvim *ARGS: (check nvim + ' --clean --headless' ARGS)

[no-cd]
[private]
check vimcmd *ARGS:
    test -d vader.vim || {{ git }} clone --depth 1 https://github.com/junegunn/vader.vim.git
    {{ vimcmd }} \
        -c 'let g:ledger_bin = "{{ ledger }}"' \
        -c {{ quote("let &runtimepath=\"" + justfile_directory() + "/vader.vim," + justfile_directory() + ",\" . &runtimepath") }} \
        -c 'filetype detect' \
        -c 'source vader.vim/plugin/vader.vim' \
        {{ ARGS }} \
        '+Vader! spec/*'