[tmva][sofie] Detect ONNX input files for tests at runtime

This means we don't need to do a clean CMake build everytime a new ONNX
file is added anymore, as so far the ONNX files for tests were copied at
configuration time with CMakes `configure_file`.

Author: guitargeek

tmva/sofie/test/CMakeLists.txt

@@ -13,38 +13,37 @@
 if (NOT ONNX_MODELS_DIR)
   set(ONNX_MODELS_DIR input_models)
 endif()
+get_filename_component(ONNX_MODELS_DIR "${ONNX_MODELS_DIR}" ABSOLUTE)
 
-# Finding .onnx files to be parsed and creating the appropriate code to
-# parse all file. It is much faster to combine all parsing in a single executable
-# which will avoid initialization time (especially when using ROOT)
-set(CAPTURE_STR "EmitModel( \"@1\", \"@2\");")
-set(ALL_CAPTURES "")
-# Finding .onnx files to be parsed and creating the appropriate command
-file(GLOB ONNX_FILES "${ONNX_MODELS_DIR}/*.onnx")
-foreach(onnx_file ${ONNX_FILES})
-  get_filename_component(fname ${onnx_file} NAME_WE)
-  get_filename_component(fdir ${onnx_file} DIRECTORY)
-  string(REPLACE "@1" ${onnx_file} cap ${CAPTURE_STR})
-  string(REPLACE "@2" ${fname} cap ${cap})
-  list(APPEND ALL_CAPTURES ${cap})
-endforeach()
-string(REPLACE ";" ";\n" EMIT_CAPTURES "${ALL_CAPTURES}")
-configure_file(EmitFromONNX.cxx.in EmitFromONNX_all.cxx @ONLY)
-
-ROOTTEST_GENERATE_EXECUTABLE(emitFromONNX EmitFromONNX_all.cxx
+# The parsing of all .onnx files is combined in a single executable, which is
+# much faster than one process per model because it avoids the repeated
+# initialization time (especially when using ROOT).
+#
+# The list of models is globbed at build time by GenerateEmitFromONNX.cmake,
+# which (re-)generates EmitFromONNX_all.cxx right before the emitFromONNX
+# executable is built. Like this, adding or removing a model does not require
+# re-running CMake, and the generated file is only touched when the model list
+# actually changed, so no needless recompilation is triggered.
+set(EMIT_FROM_ONNX_SOURCE ${CMAKE_CURRENT_BINARY_DIR}/EmitFromONNX_all.cxx)
+add_custom_target(SofieEmitFromONNXSource
+  COMMAND ${CMAKE_COMMAND}
+          -DONNX_MODELS_DIR=${ONNX_MODELS_DIR}
+          -DTEMPLATE_FILE=${CMAKE_CURRENT_SOURCE_DIR}/EmitFromONNX.cxx.in
+          -DOUTPUT_FILE=${EMIT_FROM_ONNX_SOURCE}
+          -P ${CMAKE_CURRENT_SOURCE_DIR}/GenerateEmitFromONNX.cmake
+  BYPRODUCTS ${EMIT_FROM_ONNX_SOURCE}
+  COMMENT "Updating EmitFromONNX_all.cxx from the ONNX models in ${ONNX_MODELS_DIR}")
+
+ROOTTEST_GENERATE_EXECUTABLE(emitFromONNX ${EMIT_FROM_ONNX_SOURCE}
                              LIBRARIES protobuf::libprotobuf ROOTTMVASofie ROOTTMVASofieParser
+                             DEPENDS SofieEmitFromONNXSource
                              FIXTURES_SETUP sofie-compile-models-onnx-build)
 
-configure_file(${CMAKE_CURRENT_SOURCE_DIR}/input_models/ConvAddReluFuseBug.onnx
-               ${CMAKE_CURRENT_BINARY_DIR}/ConvAddReluFuseBug.onnx COPYONLY)
-ROOT_ADD_GTEST(TestParseConvAddFusion TestParseConvAddFusion.cxx
-               LIBRARIES Core ROOTTMVASofie ROOTTMVASofieParser)
-
 # silence protobuf warnings seen in version 3.0 and 3.6. Not needed from protobuf version 3.17
 target_compile_options(emitFromONNX PRIVATE -Wno-unused-parameter -Wno-array-bounds)
 
 ROOTTEST_ADD_TEST(SofieCompileModels_ONNX
-  COMMAND ${CMAKE_COMMAND} -E env ROOTIGNOREPREFIX=1 ./emitFromONNX ${onnx_file} ${CMAKE_CURRENT_BINARY_DIR}/${fname}
+  COMMAND ${CMAKE_COMMAND} -E env ROOTIGNOREPREFIX=1 ./emitFromONNX
   FIXTURES_REQUIRED sofie-compile-models-onnx-build
   FIXTURES_SETUP sofie-compile-models-onnx
 )

tmva/sofie/test/EmitFromONNX.cxx.in

@@ -9,8 +9,14 @@
 #include "TMVA/RModel.hxx"
 #include "TMVA/RModelParser_ONNX.hxx"
 
+#include <exception>
+#include <iostream>
+#include <string>
+
+// Returns the number of failures (0 or 1), so that a model that fails to
+// parse doesn't prevent the emission of the remaining models.
 int EmitModel(std::string filename, std::string outname)
-{
+try {
    using namespace TMVA::Experimental::SOFIE;
 
    std::cout << "parsing file ..." << filename << std::endl;
@@ -50,11 +56,15 @@ int EmitModel(std::string filename, std::string outname)
    }
 
    return 0;
+} catch (std::exception const &e) {
+   std::cerr << "Failed to emit model " << filename << ": " << e.what() << std::endl;
+   return 1;
 }
 
-int main(int argc, char *argv[])
+int main()
 {
+   int nFailures = 0;
    // clang-format off
-   @EMIT_CAPTURES@;
-   // clang-format on
+@EMIT_CAPTURES@   // clang-format on
+   return nFailures;
 }

tmva/sofie/test/GenerateEmitFromONNX.cmake

@@ -0,0 +1,30 @@
+# Copyright (C) 1995-2026, Rene Brun and Fons Rademakers.
+# All rights reserved.
+#
+# For the licensing terms see $ROOTSYS/LICENSE.
+# For the list of contributors see $ROOTSYS/README/CREDITS.
+
+# Generate EmitFromONNX_all.cxx from all .onnx models found in ONNX_MODELS_DIR.
+#
+# This script is run at build time (see CMakeLists.txt in this directory), so
+# that newly added models are picked up without re-running CMake. The output
+# file is only touched when its content changed, to avoid needless
+# recompilation of the emitFromONNX executable.
+#
+# Expected variables:
+#   ONNX_MODELS_DIR - directory containing the .onnx input models
+#   TEMPLATE_FILE   - path to EmitFromONNX.cxx.in
+#   OUTPUT_FILE     - path of the generated translation unit
+
+file(GLOB onnx_files "${ONNX_MODELS_DIR}/*.onnx")
+list(SORT onnx_files)
+
+set(EMIT_CAPTURES "")
+foreach(onnx_file IN LISTS onnx_files)
+  get_filename_component(fname "${onnx_file}" NAME_WE)
+  string(APPEND EMIT_CAPTURES "   nFailures += EmitModel(\"${onnx_file}\", \"${fname}\");\n")
+endforeach()
+
+configure_file("${TEMPLATE_FILE}" "${OUTPUT_FILE}.tmp" @ONLY)
+execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different "${OUTPUT_FILE}.tmp" "${OUTPUT_FILE}")
+file(REMOVE "${OUTPUT_FILE}.tmp")