ahk_scripts.ahk

; ================================================================================
; # countdown.ahk
; ================================================================================
^F3:: {
    SetT := InputBox('How long from now? (minutes)', 'w250 h100').value * 60

    MyGui := Gui('+AlwaysOnTop -Caption -Border -SysMenu +ToolWindow', 'Sleep Time Left')
    MyGui.MarginX := 2
    MyGui.MarginY := 0
    MyGui.SetFont('s24 bold', 'Verdana')

    MyGui.TX := MyGui.AddText('x2 y6 h40 cGreen Center', Frmt(MyGui.initSecs := SetT))
    MyGui.TX.OnEvent('Click', (*) => PostMessage(0xA1, 2,,, 'A'))

    MyGui.Progress1 := MyGui.AddProgress('x0 y0 wp h5 -Smooth Range0-' SetT ' vProgress1', MyGui.ProgNum := SetT)

    Cuar          := Floor(SetT/4)
    MyGui.Cuar1   := Cuar*1
    MyGui.Cuar2   := Cuar*2
    MyGui.Cuar3   := Cuar*3

    MyGui.TX.SetFont('s23')
    MyGui.Show

    MyGui.Progress1.GetPos(,, &w)
    MyGui.Progress1.Move(,, w+MyGui.MarginX*2)

    ; start countdown
    SetTimer(SubtractTime, 1000)

    SubtractTime()
    {
        MyGui.Progress1.value-- ; subtract one tick from progress bar
        MyGui.TX.Value := Frmt(--MyGui.initSecs) ; update time

        if MyGui.TX.Value = '00:00' { ; if time is up
            Sleep(1000) ; wait one more second
            SetTimer(SubtractTime, 0) ; stop countdown timer
            MyGui.Destroy() ; destroy gui
            return Msgbox("End of countdown!", 'Reminder', '64') ; show reminder message
        }

        switch MyGui.initSecs
        {
            case MyGui.Cuar2:
                MyGui.TX.SetFont('s24 cFFA500')
                MyGui.Progress1.Opt('cFFA500')

            case MyGui.Cuar1:
                MyGui.TX.SetFont('s24 cRed')
                MyGui.Progress1.Opt('cRed')
        }
    }

    Frmt(secs)
    {
        time := 20000101
        time := DateAdd(time, secs, 'Seconds')
        mmss := FormatTime(time, (secs < 3600 ? 'mm:ss' : 'HH:mm:ss'))
        return mmss
    }
}

; ================================================================================
; # g915_n.ahk
; ================================================================================
; Fix repeating key problem with Logitech G915
; https://stackoverflow.com/questions/68349486/how-to-make-an-autohotkey-script-to-fix-my-keyboard-repeating-key-problem
*n:: ; When 'n' is pressed (with or without modifiers like `Shift` or `Alt`)
{
    Send("{Blind}n") ; Send 'n' blindly to the computer
    Sleep(100) ; Then delay for a duration of one second [change to taste]
    return
}

; ================================================================================
; # kb_shcut.ahk
; ================================================================================
; Print current date
:*:!date::
{
    CurrentDateTime := FormatTime(, "dddd, yyyy-MM-dd")
    SendInput(CurrentDateTime)
    return
}

; Print current time
:*:!time::
{
    CurrentDateTime := FormatTime(, "HH:mm:ss")
    SendInput(CurrentDateTime)
    return
}

; Open Google Calendar
:*:!gc::
{
    Run "firefox.exe https://calendar.google.com/calendar/u/0/"
    return
}

; ================================================================================
; # mouse_move.ahk
; ================================================================================
n := 10 ; number of intervals
w := A_ScreenWidth / n

move_5px()
{
    MouseGetPos(&xpos, &ypos)
    MouseMove(-5, 0, 10, "R")
    Sleep(100)
}

^M:: {
    SetTimer(move_5px, 1000)
}

; ================================================================================
; # procs.ahk
; ================================================================================
^!Up:: {
    procs := ['turtl.exe', 'Spotify.exe', 'firefox.exe', 'DiscordCanary.exe', 'Routine.exe', 'Antidote.exe', 'slack.exe', 'Spike.exe', 'Telegram.exe', 'KeePass.exe']

    DoProcs(*) {
        Input := MyInput.Text
        if (Input = "close") {
            CloseProcs()
            OpenCloseGui.Hide
        } else if (Input = "open") {
            RunProcs()
            OpenCloseGui.Hide
        } else {
            MsgBox("Invalid input. Need 'open' or 'close'")
        }
        return
    }

    CloseProcs(*) {
        for p in procs
            if (PID := ProcessExist(p)) {
                ProcessClose(PID)
            }
        return
    }

    RunProcs(*) {
        for p in procs
            if (!PID := ProcessExist(p)) {
                Run "shell:startup" p
            }
        return
    }

    OpenCloseGui := Gui('+ToolWindow', 'Open/Close')
    MyInput := OpenCloseGui.AddEdit("vInputField")
    MyBtn := OpenCloseGui.AddButton("Default w80", "OK")
    MyBtn.OnEvent("Click", DoProcs)
    OpenCloseGui.Show
}

; ================================================================================
; # run_hotkeys.ahk
; ================================================================================
#C::
{
    Run "C:\Program Files\PowerShell\7\pwsh.exe"
}

; ================================================================================
; # setontop.ahk
; ================================================================================
^SPACE::WinSetAlwaysOnTop -1, "A"

; ================================================================================
; # typing_hotkeys.ahk
; ================================================================================
; Note: these hotkeys were designed with the French AZERTY keyboard layout in mind.

^!Space::Send("{U+00A0}") ; CTRL + ALT + Space = non-breaking space (nbsp)

^!SC00A::Send("{U+00C7}") ; CTRL + ALT + ç = uppercase C-cedilla (Ç)

^SC00B::Send("{U+00C0}") ; CTRL + à = uppercase A with grave accent (À)

^!SC008::Send("{U+00C8}") ; CTRL + ALT + è = uppercase E with grave accent (È)

^!SC003::Send("{U+00C9}") ; CTRL + ALT + é = uppercase E with acute accent (É)

^<!SC032::Send("{U+00A0}{U+003F}") ; CTRL + ALT + , = nbsp + question mark

^<!SC035::Send("{U+00A0}{U+0021}") ; CTRL + ALT + ! = nbsp + exclamation mark

^<!SC033::Send("{U+00A0}{U+003B}{U+0020}") ; CTRL + ALT + ; = nbsp + semicolon + normal space

^<!SC034::Send("{U+00A0}{U+003A}{U+0020}") ; CTRL + ALT + : = nbsp + colon + normal space

^!SC056::Send("{U+00AB}{U+00A0}") ; CTRL + ALT + < = French opening quotation mark + nbsp

^SC056::Send("{U+00A0}{U+00BB}") ; CTRL + < = nbsp + French closing quotation mark

^<!SC02D::Send("{U+00A0}{U+00D7}{U+00A0}") ; CTRL + ALT + x = nbsp + multiplication sign + nbsp

^SC04A::Send("{U+2013}") ; CTRL + - (Numpad) = en-dash (–)

^<!SC04A::Send("{U+2014}") ; CTRL + ALT + - (Numpad) = em-dash (—)

<+SC04A::Send("{U+2212}") ; RShift + - (Numpad) = minus sign (−)

<!SC009::Send("{U+005C}") ; ALT + _ = backslash (\)

<!SC033::Send("{U+00B7}") ; ALT + ; = interpunct (·)

<!SC008::Send("{U+0060}") ; ALT + è = backtick (`)

<!SC003::Send("{U+007E}") ; ALT + é = tilde (~)

>+SC00C::Send("{U+00BA}") ; RShift + ) = ordinal indicator (º)

!SC012::Send("{U+1D49}") ; ALT + e = superscript e (ᵉ)

!SC013::Send("{U+02B3}") ; ALT + r = superscript r (ʳ)

:*:!oe::{U+0153} ; exclamation mark + oe = œ

:*:...::{U+2026} ; 3 full stops = ellipsis as 1 character (…)

:*:->::{U+2192} ; hyphen + > = right arrow (→)

; ================================================================================
; # uncopy_newlines.ahk
; ================================================================================
^+C:: {
    Suspend(1)
    A_Clipboard := ""
    Send "^c"
    ClipWait(50)
    A_Clipboard := RegExReplace(A_Clipboard, "(\R)", " ")
    Suspend(0)
    return
}

; ================================================================================
; # audio_switch.ahk
; ================================================================================
; https://www.autohotkey.com/boards/viewtopic.php?f=76&t=49980&p=387886#p387886

speakersName := "Speakers (Realtek(R) Audio)"
headphonesName := "Headphones (KT USB Audio)"

List := EnumAudioEndpoints()
Devices := ""
for Device in List
    Devices .= Format("{} ({})`n`n", Device["Name"], Device["ID"])
; for debugging
;MsgBox(Devices)

^SC130::
{
    SetDefaultEndpoint(GetDeviceID(List, speakersName))
    ShowIndicator(speakersName)
}

+SC130::
{
    SetDefaultEndpoint(GetDeviceID(List, headphonesName))
    ShowIndicator(headphonesName)
}

; --- Indicator GUI ---
ShowIndicator(text) {
    g := Gui("+AlwaysOnTop -Caption +ToolWindow +Border")
    g.BackColor := "White"
    g.SetFont("s12 bold", "Segoe UI")
    g.AddText("Center w200 h60", text)

    ; Position centered at bottom
    screenW := A_ScreenWidth
    screenH := A_ScreenHeight
    winW := 220
    winH := 90
    x := (screenW - winW) // 2
    y := screenH - winH - 60

    g.Show("x" x " y" y " w" winW " h" winH " NA")

    SetTimer(() => g.Destroy(), -1500)
}

/*
    Generates a collection of audio endpoint devices that meet the specified criteria.
    Parameters:
        DataFlow:
            The data-flow direction for the endpoint devices in the collection.
            0   Audio rendering stream. Audio data flows from the application to the audio endpoint device, which renders the stream.
            1   Audio capture stream. Audio data flows from the audio endpoint device that captures the stream, to the application.
            2   Audio rendering or capture stream. Audio data can flow either from the application to the audio endpoint device, or from the audio endpoint device to the application.
        StateMask:
            The state or states of the endpoints that are to be included in the collection.
            1   Active. The audio adapter that connects to the endpoint device is present and enabled. In addition, if the endpoint device plugs into a jack on the adapter, then the endpoint device is plugged in.
            2   Disabled. The user has disabled the device in the Windows multimedia control panel (Mmsys.cpl).
            4   Not present. The audio adapter that connects to the endpoint device has been removed or disabled.
            8   Unplugged. The audio adapter that contains the jack for the endpoint device is present and enabled, but the endpoint device is not plugged into the jack. Only a device with jack-presence detection can be in this state.
    Return value:
        Returns an array of Map objects with the following keys:
        ID      Endpoint ID string that identifies the audio endpoint device.
        Name    The friendly name of the endpoint device.
*/
EnumAudioEndpoints(DataFlow := 2, StateMask := 1)
{
    List := []

    ; IMMDeviceEnumerator interface.
    ; https://docs.microsoft.com/en-us/windows/win32/api/mmdeviceapi/nn-mmdeviceapi-immdeviceenumerator
    IMMDeviceEnumerator := ComObject("{BCDE0395-E52F-467C-8E3D-C4579291692E}", "{A95664D2-9614-4F35-A746-DE8DB63617E6}")

    ; IMMDeviceEnumerator::EnumAudioEndpoints method.
    ; https://docs.microsoft.com/en-us/windows/win32/api/mmdeviceapi/nf-mmdeviceapi-immdeviceenumerator-enumaudioendpoints
    ComCall(3, IMMDeviceEnumerator, "UInt", DataFlow, "UInt", StateMask, "UPtrP", &IMMDeviceCollection:=0)

    ; IMMDeviceCollection::GetCount method.
    ; https://docs.microsoft.com/en-us/windows/win32/api/mmdeviceapi/nf-mmdeviceapi-immdevicecollection-getcount
    ComCall(3, IMMDeviceCollection, "UIntP", &DevCount:=0)  ; Retrieves a count of the devices in the device collection.

    loop DevCount
    {
        List.Push(Device := Map())

        ; IMMDeviceCollection::Item method.
        ; https://docs.microsoft.com/en-us/windows/win32/api/mmdeviceapi/nf-mmdeviceapi-immdevicecollection-item
        ComCall(4, IMMDeviceCollection, "UInt", A_Index-1, "UPtrP", &IMMDevice:=0)

        ; IMMDevice::GetId method.
        ; https://docs.microsoft.com/en-us/windows/win32/api/mmdeviceapi/nf-mmdeviceapi-immdevice-getid
        ComCall(5, IMMDevice, "PtrP", &pBuffer:=0)
        Device["ID"] := StrGet(pBuffer)
        DllCall("Ole32.dll\CoTaskMemFree", "UPtr", pBuffer)

        ; MMDevice::OpenPropertyStore method.
        ; https://docs.microsoft.com/en-us/windows/win32/api/mmdeviceapi/nf-mmdeviceapi-immdevice-openpropertystore
        ComCall(4, IMMDevice, "UInt", 0x00000000, "UPtrP", &IPropertyStore:=0)

        Device["Name"] := GetDeviceProp(IPropertyStore, "{A45C254E-DF1C-4EFD-8020-67D146A850E0}", 14)

        ObjRelease(IPropertyStore)
        ObjRelease(IMMDevice)
    }

    ObjRelease(IMMDeviceCollection)

    return List
}

/*
    Set default audio render endpoint.
    Role:
        0x1   Default Device.
        0x2   Default Communication Device.
*/
SetDefaultEndpoint(DeviceID, Role := 3)
{
    ; Undocumented COM-interface IPolicyConfig.
    IPolicyConfig := ComObject("{870AF99C-171D-4F9E-AF0D-E63Df40c2BC9}", "{F8679F50-850A-41CF-9C72-430F290290C8}")
    if (Role & 0x1)
        ComCall(13, IPolicyConfig, "Str", DeviceID, "Int", 0)  ; Default Device
    if (Role & 0x2)
        ComCall(13, IPolicyConfig, "Str", DeviceID, "Int", 2)  ; Default Communication Device
}

/*
    Device Properties (Core Audio APIs)
    https://docs.microsoft.com/en-us/windows/win32/coreaudio/device-properties

    026E516E-B814-414B-83CD-856D6FEF4822, 2   The friendly name of the audio adapter to which the endpoint device is attached.
    A45C254E-DF1C-4EFD-8020-67D146A850E0, 2   The device description of the endpoint device.
    A45C254E-DF1C-4EFD-8020-67D146A850E0,14   The friendly name of the endpoint device.
*/
InitDeviceProp(clsid, n)
{
    clsid := CLSIDFromString(clsid, Buffer(16+4))
    NumPut("Int", n, clsid, 16)
    return clsid
}

GetDeviceProp(ptr, clsid, n)
{
    ; IPropertyStore::GetValue method.
    ; https://docs.microsoft.com/en-us/windows/win32/api/propsys/nf-propsys-ipropertystore-getvalue
    ComCall(5, ptr, "Ptr", InitDeviceProp(clsid, n), "Ptr", pvar := PropVariant())
    return String(pvar)
}

GetDeviceID(list, name)
{
    for device in list
        if InStr(device["Name"], name)
            return device["ID"]
    throw
}

CLSIDFromString(Str, Buffer := 0)
{
    if (!Buffer)
        Buffer := Buffer(16)
    DllCall("Ole32\CLSIDFromString", "Str", Str, "Ptr", Buffer, "HRESULT")
    return Buffer
}

class PropVariant
{
    __New()
    {
        this.buffer := Buffer(A_PtrSize == 4 ? 16 : 24)
        this.ptr    := this.buffer.ptr
        this.size   := this.buffer.size
    }

    __Delete()
    {
        DllCall("Ole32\PropVariantClear", "Ptr", this.ptr, "HRESULT")
    }

    ToString()
    {
        return StrGet(NumGet(this.ptr, 8, "UPtr"))  ; LPWSTR PROPVARIANT.pwszVal
    }
}