quaalude/flake.nix at master · typeclasses/quaalude · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
{
  description = "quaalude";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.05";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils }:
    let packageName = "quaalude";
    in flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs { inherit system; };

        project = pkgs.haskellPackages.developPackage {
          root = ./quaalude;
          name = packageName;
        };

        inherit (pkgs.lib) fold composeExtensions concatMap attrValues;

        combineOverrides = old:
          fold composeExtensions (old.overrides or (_: _: { }));

      in
      {
        defaultPackage = self.packages.${system}.${packageName};

        packages = {
          "${packageName}" = project;

          testConfigurations =
            let

              inherit (pkgs.haskell.lib) dontCheck;
              makeTestConfiguration =
                let defaultPkgs = pkgs;
                in { pkgs ? defaultPkgs, ghcVersion, overrides ? new: old: { } }:
                  let inherit (pkgs.haskell.lib) dontCheck packageSourceOverrides;
                  in (pkgs.haskell.packages.${ghcVersion}.override (old: {
                    overrides = combineOverrides old [
                      (packageSourceOverrides { quaalude = ./quaalude; })
                      (new: old: { })
                      overrides
                    ];
                  })).quaalude;
            in
            rec {
              ghc-9-6 = makeTestConfiguration { ghcVersion = "ghc96"; };
              ghc-9-8 = makeTestConfiguration { ghcVersion = "ghc98"; };
              ghc-9-10 = makeTestConfiguration { ghcVersion = "ghc910"; };
              all = pkgs.symlinkJoin {
                name = "quaalude";
                paths = [ ghc-9-6 ghc-9-8 ghc-9-10 ];
              };
            };
        };
      });
}